home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Geos / GEOS128 / GeosD81 / cs20.d81 / gEOdIR pRINT (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  1.4 KB  |  45 lines
  1. 0  
  2. 1 REM  BASIC GEODIR TRUE-ASCII PRINT
  3. 2 REM  (C) 1993 06 11 PETER KARLSSON
  4. 3 REM  BASERAT P] BASIC GEODIR
  5. 4  
  6. 5 REM  V1.0
  7. 6  
  8. 7 REM  SKRIVER UT EN GEOS-DISKS
  9. 8 REM  KATALOG P] EN SKRIVARE MED
  10. 9 REM  TRUE-ASCII
  11. 10  
  12. 11 OPEN4,4
  13. 12 PRINT"รดBASIC GEODIR TRUE-ASCII PRINT"
  14. 13 PRINT"SKRIVER UT...":E$=CHR$(0):DIMN$(16)
  15. 14 OPEN15,8,15,"I0":OPEN2,8,2,"#":PRINT#15,"U1 2 0 18 0":PRINT#15,"B-P 2 189"
  16. 15 GET#2,DI$:PRINT#15,"B-P 2 144":FORI=1TO16:GET#2,N$(I):NEXT:DI=ASC(DI$+E$)
  17. 16 FORI=1TO16:N=ASC(N$(I)+E$)
  18. 17 PRINT#4,CHR$(N);:NEXT:FI=.:KB=.
  19. 18 IFDI=66THENPRINT#4," Systemdiskett.":GOTO21
  20. 19 IFDI=80THEN4," Applikationsdiskett.":GOTO21
  21. 20 PRINT#4," Arbetsdiskett."
  22. 21 PRINT#15,"B-P 2 0":GET#2,T$,S$
  23. 22 T=ASC(T$+E$):S=ASC(S$+E$)
  24. 23 IFT=.THEN40
  25. 24 PRINT#15,"U1 2 0"T;S
  26. 25 FORA=1TO8:B=2+(A-1)*32:PRINT#15,"B-P 2"B
  27. 26 IFPEEK(198)<>.THENCLOSE2:CLOSE15:END
  28. 27 GET#2,TY$:IFTY$=""GOTO39
  29. 28 GET#2,T$,S$:FORI=1TO16:GET#2,N$(I):NEXT
  30. 29 GET#2,A$,A$,A$,A$,YE$,MO$,DA$,HO$,MI$,L$,H$
  31. 30 BL=ASC(H$+E$)*256+ASC(L$+E$):TY=ASC(TY$+E$):T=ASC(T$+E$):S=ASC(S$+E$)
  32. 31 YE=ASC(YE$+E$):MO=ASC(MO$+E$):DA=ASC(DA$+E$):HO=ASC(HO$+E$):MI=ASC(MI$+E$)
  33. 32 FORI=1TO16:N=ASC(N$(I)+E$)
  34. 33 PRINT#4,CHR$(N);:NEXT
  35. 34 PRINT#4,":"MID$("DSPUR",(TYAND7)+1,1)MID$(" <",(TYAND192)/192+1,1)":";
  36. 35 IFYE=0ANDMO=0ANDDA=0OR(TYAND7)=4THENPRINT"              ";:GOTO38
  37. 36 PRINT#4,RIGHT$(STR$(100+YE),2)"-"RIGHT$(STR$(100+MO),2)"-"RIGHT$(STR$(100+DA),2);
  38. 37 PRINT#4," "RIGHT$(STR$(100+HO),2)"."RIGHT$(STR$(100+MI),2)" ";
  39. 38 K=BL/4:PRINT#4,MID$(STR$(INT(K+.5)),2)"Kb":FI=FI+1:KB=KB+K
  40. 39 NEXT:GOTO21
  41. 40 PRINT#4,"----------------"SPC(19)"-----"
  42. 41 SP$="                                   "
  43. 42 PRINT#4,LEFT$(MID$(STR$(FI),2)+" Filer"+SP$,35)MID$(STR$(INT(KB+.5)),2)"Kb"
  44. 43 CLOSE2:CLOSE15:CLOSE4
  45.